@echo off
title %~nx0
set cnt=0

echo:
echo     ==========================================================================
echo           net use
echo     ==========================================================================
echo:
for /f "usebackq delims=" %%a in (`net use ^| findstr \\\\`) do (
echo     %%a
)
echo:
echo     ==========================================================================
echo           net view
echo     ==========================================================================
echo:
for /f "usebackq tokens=1" %%x in (`net view ^| findstr \\\\`) do (
echo                 %%x
)
echo:
echo:

for /f "usebackq tokens=1" %%x in (`net view ^| findstr \\\\`) do (
set "test=%%x"
call :SERVER
)

if not defined master_browser (
nbtstat -n
nbtstat -n | findstr __MSBROWSE__ >nul
)
if not ERRORLEVEL 1 (
set master_browser=%ComputerName%
)
GOTO SHOW

:SERVER
set test=%test:\\=%
echo:       --------------------------------------------------------------
echo             %test%
echo:       --------------------------------------------------------------
if /i "%test%"=="%ComputerName%" (
nbtstat -n
nbtstat -n | findstr __MSBROWSE__ >nul
echo:
echo:
) else (
nbtstat -a %test%
nbtstat -a %test% | findstr __MSBROWSE__ >nul
echo:
)

if not ERRORLEVEL 1 (
if not defined master_browser (
set master_browser=%test%
) else (
set master_browser_2=%test%
))
GOTO :EOF

:SHOW
if defined master_browser (
for /f "tokens=2 delims=[]" %%x in ('ping -a -4 -n 1 -w 50 %master_browser%') do (
set "Master_IP=%%x"
))
if defined master_browser_2 (
for /f "tokens=2 delims=[]" %%x in ('ping -a -4 -n 1 -w 50 %master_browser_2%') do (
set "Master2_IP=%%x"
))

echo:
echo        ==============================================================
echo         * Master Browser    =   %Master_IP% - %master_browser%
if defined master_browser_2 (
echo         * Master Browser[2] =   %Master2_IP% - %master_browser_2%
)
echo        ==============================================================
echo:
echo                     *** 何かキーを押すと閉じます *** 
echo:
echo:
pause >nul